OpenEdge Development:<br />Progress 4GL Reference THIS-PROCEDURE system handle

A handle to the current procedure object. This object allows you to read and modify the context of the current procedure.

Syntax


`procedure-handle` [ :`attribute` \| :`method` ]

For Web services, this object is instantiated when you execute the RUN ON statement that references a Web service server object.

Attributes

Methods

The following procedure is designed to run both persistently and non-persistently. It sets up a query on the customer table of the sports database that is selectable by name or balance.

ADM-DATA attribute	ASYNC-REQUEST-COUNT attribute	CURRENT-WINDOW attribute
DB-REFERENCES attribute	FILE-NAME attribute	INTERNAL-ENTRIES attribute
NAME attribute	NEXT-SIBLING attribute	PERSISTENT attribute
PREV-SIBLING attribute	PRIVATE-DATA attribute	PROXY attribute
PUBLISHED-EVENTS attribute	REMOTE attribute	SERVER attribute
SUPER-PROCEDURES attribute	TRANSACTION attribute	TYPE attribute
UNIQUE-ID attribute

ADD-SUPER-PROCEDURE( ) method	GET-SIGNATURE( ) method
REMOVE-SUPER-PROCEDURE( ) method	SET-CALLBACK-PROCEDURE( ) method

r-thispr.p
DEFINE QUERY custq FOR customer. DEFINE BROWSE custb QUERY custq DISPLAY name balance phone WITH 10 DOWN. DEFINE BUTTON bName LABEL "Query on Name". DEFINE BUTTON bBalance LABEL "Query on Balance". DEFINE BUTTON bCancel LABEL "Cancel". DEFINE FRAME CustFrame custb SKIP bName bBalance bCancel. DEFINE VARIABLE custwin AS WIDGET-HANDLE. ON CHOOSE OF bName IN FRAME CustFrame DO: custwin:TITLE = "Customers by Name". OPEN QUERY custq FOR EACH customer BY name. END. ON CHOOSE OF bBalance IN FRAME CustFrame DO: custwin:TITLE = "Customers by Balance". OPEN QUERY custq FOR EACH customer BY balance DESCENDING. END.
IF THIS-PROCEDURE:PERSISTENT THEN DO: THIS-PROCEDURE:PRIVATE-DATA = "Customer Browse". CREATE WIDGET-POOL. END. CREATE WINDOW custwin ASSIGN TITLE = "Customer Browser" SCROLL-BARS = FALSE MAX-HEIGHT-CHARS = FRAME CustFrame:HEIGHT-CHARS MAX-WIDTH-CHARS = FRAME CustFrame:WIDTH-CHARS. THIS-PROCEDURE:CURRENT-WINDOW = custwin. ENABLE ALL WITH FRAME CustFrame. IF THIS-PROCEDURE:PERSISTENT THEN DO: ON CHOOSE OF bCancel IN FRAME CustFrame DO: RUN destroy-query. END. END. ELSE DO: WAIT-FOR CHOOSE OF bCancel IN FRAME CustFrame. END. PROCEDURE destroy-query: DELETE PROCEDURE THIS-PROCEDURE. DELETE WIDGET-POOL. END.

r-thispr.p

DEFINE QUERY custq FOR customer.
DEFINE BROWSE custb QUERY custq
    DISPLAY name balance phone WITH 10 DOWN.
DEFINE BUTTON bName LABEL "Query on Name".
DEFINE BUTTON bBalance LABEL "Query on Balance".
DEFINE BUTTON bCancel LABEL "Cancel".

DEFINE FRAME CustFrame custb SKIP
    bName bBalance bCancel.
    
DEFINE VARIABLE custwin AS WIDGET-HANDLE.

ON CHOOSE OF bName IN FRAME CustFrame DO:
    custwin:TITLE = "Customers by Name".
    OPEN QUERY custq FOR EACH customer BY name.
END.        

ON CHOOSE OF bBalance IN FRAME CustFrame DO:
    custwin:TITLE = "Customers by Balance".
    OPEN QUERY custq FOR EACH customer BY balance DESCENDING.
END.

IF THIS-PROCEDURE:PERSISTENT THEN DO:
    THIS-PROCEDURE:PRIVATE-DATA = "Customer Browse".
    CREATE WIDGET-POOL.
END.

CREATE WINDOW custwin
    ASSIGN
        TITLE = "Customer Browser"
        SCROLL-BARS = FALSE
        MAX-HEIGHT-CHARS = FRAME CustFrame:HEIGHT-CHARS
        MAX-WIDTH-CHARS = FRAME CustFrame:WIDTH-CHARS.
        
THIS-PROCEDURE:CURRENT-WINDOW = custwin.

ENABLE ALL WITH FRAME CustFrame.

IF THIS-PROCEDURE:PERSISTENT THEN DO:
    ON CHOOSE OF bCancel IN FRAME CustFrame DO:
        RUN destroy-query.
    END.
END.
ELSE DO: 
    WAIT-FOR CHOOSE OF bCancel IN FRAME CustFrame.
END.

PROCEDURE destroy-query:
    DELETE PROCEDURE THIS-PROCEDURE.
    DELETE WIDGET-POOL.
END.

The procedure uses the THIS-PROCEDURE handle to distinguish between persistent and non-persistent instances of execution. When r-thispr.p is persistent (THIS-PROCEDURE:PERSISTENT = TRUE), it:

Sets the PRIVATE-DATA attribute to help identify it to other procedures.

Creates a private widget pool to maintain its dynamic window for as long as the procedure instance persists.

Defines a trigger to delete the procedure when it is terminated. Note that the trigger calls the internal procedure destroy-query, which can be executed by other external procedures to delete r-thispr.p when it is persistent. This destroy-query routine references the THIS-PROCEDURE handle to delete its persistent parent. It also deletes the widget pool that maintains the dynamic window.

When r-thispr.p is non-persistent (THIS-PROCEDURE:PERSISTENT = FALSE), it invokes a WAIT-FOR statement rather than defining a trigger to terminate the procedure. It does not need to create a widget pool or maintain any other persistent context.

Note that because both persistent and non-persistent instances of this procedure use a dynamic window separate from the default window, r-thispr.p assigns the window’s handle to the procedure’s CURRENT-WINDOW attribute. This makes the dynamic window current whether or not the procedure is persistent. However, when the procedure is persistent, the CURRENT-WINDOW attribute keeps the dynamic window current while other procedures execute using different windows. Because the persistent procedure has its own current window, its triggers and internal procedures do not have to reset the current window every time they execute.

Notes

The attributes supported by THIS-PROCEDURE are supported by any valid procedure handle. You can also define triggers for procedure handles. For more information, see OpenEdge Development: Progress 4GL Handbook .

By determining if the current procedure is persistent, you can decide whether or not to perform certain actions. An action that you might perform during a non-persistent procedure is to execute a WAIT-FOR statement to provide interactive I/O blocking. Actions that you might execute during a persistent procedure include creating a new window to parent all other widgets created in the procedure, or maintaining an unscoped record buffer that lasts as long as the procedure persists.

To create an instance of a persistent procedure, use the PERSISTENT option of the RUN statement.

If THIS-PROCEDURE is persistent and the NEXT-SIBLING or PREV-SIBLING attributes are invalid, THIS-PROCEDURE specifies the last or first persistent procedure instance (respectively) in the session persistent procedure chain. To check the validity of these attributes, use the VALID-HANDLE function.

You can access the handles and attributes of all persistent procedure instances in a session using the FIRST-PROCEDURE or LAST-PROCEDURE attribute of the SESSION handle.

For information on transaction objects, see OpenEdge Application Server: Developing AppServer Applications .

THIS-PROCEDURE system handle

Syntax

Attributes

Methods

Notes

See also